Yours is a smarter approach, this one is surprisingly attackable with simple brute force. I was going to write my solution similarly but the first attempt did the job in under 5.5 seconds:

module main;
import std.stdio, std.datetime, std.algorithm, std.math;

bool isPalin(ulong n)
{   if(n < 11)
        return false;
    ulong high = 10UL ^^ cast(ulong) log10(n);
    while(high >= 10)
    {   ulong temp = n / high;
        if(temp != n % 10)
            return false;
        n -= temp * high;
        high /= 100;
        n  /= 10;
    }
    return true;
}

void main()
{   StopWatch sw;
    sw.start;
    enum MAX = 32_000;
    ubyte[ulong] sq;

    foreach(ulong i;2..MAX)
    {   ulong i2 = i ^^ 2;
        foreach(ulong j;2..MAX)
        {   ulong temp = i2 + j ^^ 3;
            if(temp > MAX ^^ 2)
                break;
            if(isPalin(temp))
                ++sq[temp];
        }
    }

    ulong[] arr;
    foreach(i;sq.byKey)
        if(sq[i] == 4)
            arr ~= i;

    arr.sort[0..5].reduce!("a + b").writeln;
    sw.peek.msecs.writeln("msecs");
}